#
#MPIR
#

if (WIN32)

if (CMAKE_CL_64)
  set (MPIR_PLATFORM x64)
else (CMAKE_CL_64)
  set (MPIR_PLATFORM win32)
endif (CMAKE_CL_64)

if (BUILD_SHARED_LIBS)
  set (MPIR_LIB_TYPE DLL)
else (BUILD_SHARED_LIBS)
  set (MPIR_LIB_TYPE LIB)
endif (BUILD_SHARED_LIBS)
 
if (CMAKE_BUILD_TYPE STREQUAL Debug)
  set (MPIR_DEBUG_OR_RELEASE "Debug")
else (CMAKE_BUILD_TYPE STREQUAL Debug)
  set (MPIR_DEBUG_OR_RELEASE "Release")
endif (CMAKE_BUILD_TYPE STREQUAL Debug)

if (MSVC10)
  set (MPIR_DIR build.vc10)
endif (MSVC10)
if (MSVC11)
  set (MPIR_DIR build.vc11)
endif (MSVC11)
if (MSVC12)
  set (MPIR_DIR build.vc12)
endif (MSVC12)
if (MSVC14)
  set (MPIR_DIR build.vc14)
endif (MSVC14)

set (MPIR_PROCESSOR gc) #Use only C - no assembler

if (NOT MPIR_DIR)
  message (FATAL_ERROR "Could not identify Visual Studio version")
endif (NOT MPIR_DIR)

ExternalProject_Add (
  mpir
  PREFIX ${CMAKE_INSTALL_PREFIX}
  URL http://www.mpir.org/mpir-2.7.2.tar.bz2
  URL_MD5 b31aa1ebc01b5fedf4ac43277c03feec
  BUILD_IN_SOURCE 1
  CONFIGURE_COMMAND ""
  BUILD_COMMAND ${CMAKE_COMMAND} -E chdir <SOURCE_DIR>/${MPIR_DIR} <SOURCE_DIR>/${MPIR_DIR}/msbuild.bat ${MPIR_PROCESSOR} ${MPIR_LIB_TYPE} ${MPIR_PLATFORM} ${MPIR_DEBUG_OR_RELEASE}
  INSTALL_COMMAND ${CMAKE_COMMAND} -E copy <SOURCE_DIR>/lib/${MPIR_PLATFORM}/${MPIR_DEBUG_OR_RELEASE}/mpir.h <INSTALL_DIR>/include
          COMMAND ${CMAKE_COMMAND} -E copy <SOURCE_DIR>/lib/${MPIR_PLATFORM}/${MPIR_DEBUG_OR_RELEASE}/gmp.h <INSTALL_DIR>/include
          COMMAND ${CMAKE_COMMAND} -E copy <SOURCE_DIR>/lib/${MPIR_PLATFORM}/${MPIR_DEBUG_OR_RELEASE}/mpir.lib <INSTALL_DIR>/lib
          COMMAND ${CMAKE_COMMAND} -E copy <SOURCE_DIR>/lib/${MPIR_PLATFORM}/${MPIR_DEBUG_OR_RELEASE}/mpir.lib <INSTALL_DIR>/lib/gmp.lib
)
endif (WIN32)

if (UNIX)
ExternalProject_Add (
  mpir
  PREFIX ${CMAKE_INSTALL_PREFIX}
  URL http://www.mpir.org/mpir-2.7.2.tar.bz2
  URL_MD5 b31aa1ebc01b5fedf4ac43277c03feec
  BUILD_IN_SOURCE 1
  CONFIGURE_COMMAND configure
  BUILD_COMMAND make
  INSTALL_COMMAND make install
)
endif (UNIX)